LiveCode Forums.

Code: Select all

in a button handler:

      if line 6 of gPrefs ≠ "true" then
         answer "Do you want to spend US$0.99 to...." with "Yes" and "No"
         if it = "Yes" then
            answer "Stand by while purchase is processed..." 
                mobilePurchaseCreate "com.projectiveart.1ThingDone.Shake"
                put the result into tID
                mobileEnablePurchaseUpdates
                mobilePurchaseSendRequest tID
         else
            answer "Okay, maybe some other time..."
         end if


----------------------------------

in my stack script:


on purchaseStateUpdate pPurchaseID   
   answer mobilePurchaseGet(pPurchaseID, "productID")&return&mobilePurchaseState(pPurchaseID) 
   switch mobilePurchaseState(pPurchaseID)
      case "paymentReceived"         
         if mobilePurchaseGet(pPurchaseID, "productID") is "com.projectiveart.1ThingDone.Shake" then
            put "true" into line 6 of gPrefs
         else
            put "true" into line 5 of gPrefs
         end if
         mobilePurchaseConfirmDelivery pPurchaseID
         mobileDisablePurchaseUpdates
         break
      case "error"
         answer "Error occured during purchase handling:" & return & return & mobilePurchaseError(pPurchaseID)
         mobileDisablePurchaseUpdates
         break
      case "cancelled"
         answer "Purchase cancelled."
         mobileDisablePurchaseUpdates
         break
   end switch
end purchaseStateUpdate

Code: Select all

on mouseUp
   buttonPress
   
   if mobileCanMakePurchase() then
      # purchase paid/full version
      busyStart "Purchasing...", true
      mobilePurchaseCreate "com.splash21.skidoodler.paid"
      put the result into tID
      mobileEnablePurchaseUpdates
      mobilePurchaseSendRequest tID
   else
      answer "Purchasing not available." & LF & "Please try later."
   end if
end mouseUp

Code: Select all

on purchaseStateUpdate pPurchaseID
   
   switch mobilePurchaseState(pPurchaseID)
      case "initialized"
         break
         
      case "sendingRequest"
         break
         
      case "paymentReceived"
         busyStart "", true
         answer "Purchase successful"
         put mobilePurchaseGet(pPurchaseID, "productID") into tProduct
         if tProduct ends with ".paid" then
            # full version
            put md5Hash(gAppA["Device"] & "Paid") into gAppA["Paid"]
            put false into gAppA["AdsEnabled"]
            saveAppData
         else if tProduct begins with "com.splash21.skidoodler.skoins" then
            # skoins top up
            put char 31 to -1 of tProduct into tQty
            if tQty is an integer then
               put gAppA["SkoinsPurchased"] into tTotal
               if tTotal is not an integer then put 0 into tTotal
               put tTotal + tQty into gAppA["SkoinsPurchased"]
               put md5Hash("SkoinsCheck" & gAppA["SkoinsPurchased"]) into gAppA["SkoinsHash"]
               saveAppData
            else
               answer "An error occurred: quantity = " & tQty
            end if
         end if
         mobilePurchaseConfirmDelivery pPurchaseID
         put true into tComplete
         serverRecordPurchases
         break
         
      case "error"
         busyStart "", true
         answer "Purchase failed" & LF & mobilePurchaseError(pPurchaseID)
         put true into tComplete
         break
         
      case "cancelled"
         busyStart "", true
         answer "Purchase cancelled"
         put true into tComplete
         break
         
   end switch
   
   if tComplete then
      busyStop
      mobileDisablePurchaseUpdates
   end if
   
end purchaseStateUpdate