LiveCode Forums.

Code: Select all

local sSizing,sSlope,sMinSize

on mouseDown
   if the short name of the target is among the items of  "dragRect,maskrect" then 
      put 4 into x -- define x for ratio calc
      put 3 into y -- define y for ration calc
      --to constrain to 16x9 set x to 16, y to 9
      
      -- define minimum size of the graphic
      put 100 into sMinSize
      put  y/x into sSlope -- calc the slope.  consider the first point to be 0,0 so the slope is just y of the second point / x of the second point. 
      
      -- set the flag
      put the short name of the target into sSizing
   else 
      clearflag
      pass mousedown
   end if
end mouseDown

command clearflag
   put empty into sSizing
end clearflag

on mouseup
   clearflag
end mouseup
on mouserelease
   clearFlag
end mouserelease

on mousemove x,y
   lock screen
   if sSizing is "dragRect" then
      -- get the upper left, x and y of the grc
      put the top of grc "maskRect" of me into ty
      put the left of grc "maskRect" of me into tx
      
      -- put the x of the mouseloc into tx2
      put x into tx2
      
      ### Can't shrink below specified size
      if  x - sMinSize < tx then
         put sMinSize + tx into tx2
      -- adjust tx2 to avoid making the grc smaller than desired
      end if
      
      --calculate ty2 and adjust for the offset from 0 (+ ty)
      put (sSlope * tx2 - tx) + ty into ty2
      
      -- set the positions of the maskrect and the dragrect
      set the rect of grc "maskRect" of me to tx,ty,tx2,ty2
      set the bottomright of grc "dragRect" of me to tx2,ty2
   
   else if sSizing is "maskrect" then
      grab group "maskG"
   end if
   unlock screen
end mousemove