LiveCode Forums.

Code: Select all

...
## This is the trick:
lock screen
## :-)

import paint from file "your/file/here.png"
put the formattedwidth of last img into tWidth
put the formattedheight of last img into tHeight
delete last img
unlock screen
...

Code: Select all

on mouseUp
  answer file "Bild laden.../Load image..."
  put QUOTE & it & QUOTE into bild

## Get ehight of image:
  get shell("sips -g  pixelHeight" && bild)

## It is the last word
  put last word of it into hoch

## Same for width:
  get shell("sips -g  pixelWidth" && bild)
  put last word of it into breit
  put breit & "," & hoch into fld 1
end mouseUp

Code: Select all

on WayByHex
   answer file "open:"
   if it = empty then exit WayByHex
   put it into tFile
   -- binfile or file ?
   put url("binfile:" & tfile) into tBuf -- return 001244,001244 at the end of script
   -- put url("file:" & tfile) into tBuf -- return 32124432,3212448 at the end of script
   repeat with i = 17 to 20
      put byteToNum(byte i of tBuf) after tW  
   end repeat
   repeat with i = 21 to 24
      put byteToNum(byte i of tBuf) after tH
   end repeat
   put tW & "," & tH
end WayByHex

Code: Select all

on mouseUp
  answer file "Select a PNG file:" with type "PNG File|png|PNGf"
  if it is empty then exit to top
  put it into tFile
  open file tFile for binary read
  read from file tFile for 24
  put it into tData
  close file tFile
  --
  if byte 13 to 16 of tData <> "IHDR" then
    answer "Invalid PNG format"
    exit to top
  end if
  --
  local tWidth, tHeight
  put binaryDecode("MM", byte 17 to 24 of tData, tWidth, tHeight)\
      into tNumConvertedVals
  if tNumConvertedVals <> 2 then
    answer "Couldn't decode binary data"
    exit to top
  end if
  put tWidth, tHeight
end mouseUp

Code: Select all

on mouseup
   answer folder "Select a folder with PNG files:"
   if it = empty then exit mouseup
   put the ticks into old
   lock screen
   put it into tPathFol
   put LesFilesInFol(tPathFol) into tFiles
   --put line 1 to 100 of tFiles into tFiles
   repeat for each line tLine in tFiles
      put  tPathFol & "/"& tLine into tPathIm
      open file tPathIm for binary read
        read from file tPathIm for 24
        put it into tData
        close file tPathIm
        --
        if byte 13 to 16 of tData <> "IHDR" then
         next repeat
        end if
        --
        local tWidth, tHeight
        put binaryDecode("MM", byte 17 to 24 of tData, tWidth, tHeight)\
            into tNumConvertedVals
        if tNumConvertedVals <> 2 then
         next repeat
        end if
      put tLine & numtochar(1) & tWidth & "," & tHeight & return after rGetAllDimImg
   end repeat
   delete char -1 of rGetAllDimImg
   put the ticks - old && the num of lines of rGetAllDimImg& return & rGetAllDimImg -- 2 ticks for 100 image files !
end mouseup

function LesFilesInFol tFol -- files in a folder
   put empty into rLesFilesInFol
   set the defaultFolder to tFol
   put the files into rLesFilesInFol
   filter rLesFilesInFol without ".*"
   return rLesFilesInFol
end LesFilesInFol