LiveCode Forums.

Code: Select all

// converting a list into a string...
# I am guessing you are working from a file or text field, or even from a function. 
# if you open the message box and type in the single line field 
	put the colorNames
# you will see a list of the different color names available in Lc. to put this list into a string, 
# the code would look something like (create a default stack, one button, one field) ~
// in the button code ...
on mouseUp
   put "" into field "lstField" // put the name of your field or string variable here...
   repeat for each word x in the colorNames
      put "  " & x after field "lstField" // the quotes have 2 spaces for separation...
   end repeat
end mouseUp

Code: Select all

# change the code in the button ...
on mouseUp
   put "" into field "lstField"
   put the rect of me into field "lstField"
// the rect of the button is now a string in the field...
end mouseUp

Code: Select all

on mouseUp
   put "" into field "lstField"
   put the mouseLoc into field "lstField"
// you will now see the coordinates of the mouse position on screen in the field...
// if you move it to different parts of the button, you'll see the points change...
end mouseUp

Code: Select all

public handler fitStringToRect(inout pString as String, in pFont as Font, in pMaxWidth as Number) returns nothing
   	-- Now make sure that text will fit within the available width
   	variable tTextRect as Rectangle
   	variable tEllipsis as String
   	variable tCharCount as Integer

   	put "..." into tEllipsis
   	put the number of chars in tEllipsis into tCharCount

   	put the bounds of text pString with pFont into tTextRect
   	if the width of tTextRect > pMaxWidth then
   		put tEllipsis into char -tCharCount to -1 of pString
   		put the bounds of text pString with pFont into tTextRect
   		repeat forever
   			if the width of tTextRect <= pMaxWidth or pString is tEllipsis then
   				exit repeat
   			else
   				put "..." into char -(tCharCount+1) to -1 of pString
   				put the bounds of text pString with pFont into tTextRect
   			end if
   		end repeat
   	end if
   end handler

Code: Select all

public handler colorToString(in pColor as Color, in pIncludeAlpha as Boolean) returns String
   	variable tColor as String

   	if pColor is nothing then
   		return ""
   	end if

   	put FormatInt(the rounded of ((the red of pColor) * 255)) into tColor
   	put "," & FormatInt(the rounded of ((the green of pColor) * 255)) after tColor
   	put "," & FormatInt(the rounded of ((the blue of pColor) * 255)) after tColor

   	if pIncludeAlpha then
   		put "," & FormatInt(the rounded of ((the alpha of pColor) * 255)) after tColor
   	end if

   	return tColor
   end handler

   ----------
   -- this handler converts a String of numbers to an RGBA color
   public handler stringToColor(in pString as String) returns Color
   	if the number of chars in pString is 0 then
   	     return ""
   	end if

   	variable tRed as Number
   	variable tGreen as Number
   	variable tBlue as Number
   	variable tAlpha as Number

   	variable tComponentList as List
   	split pString by "," into tComponentList

   	variable tComponentCount
   	put the number of elements in tComponentList into tComponentCount
   	if tComponentCount is not 3 and tComponentCount is not 4 then
   		// Invalid number of components detected
   		throw "Invalid color"
   	end if

   	put (element 1 of tComponentList) parsed as number into tRed
   	put (element 2 of tComponentList) parsed as number into tGreen
   	put (element 3 of tComponentList) parsed as number into tBlue

   	if tComponentCount is 4 then
   	  if element 4 of tComponentList is "inf" then
   	    put 255 into tAlpha
   	  else
        put the minimum value of [255, (element 4 of tComponentList) parsed as number] into tAlpha
   	  end if   		
   	else
   		put 255 into tAlpha
   	end if

   	return color [ tRed/255, tGreen/255, tBlue/255, tAlpha/255 ]
   end handler
   

Code: Select all

public handler stringToPoint(in pString as String) returns Point
   	variable tList as List
   	variable tPoint as Point

   	put point [0,0] into tPoint

   	split pString by ","
   	put the result into tList
   	put tList parsed as list of number into tList
   	if the number of elements in tList is 2 then
   		put point [element 1 of tList, element 2 of tList] into tPoint
   	end if

   	return tPoint
   end handler


   public handler pointToString(in pPoint as Point) returns String
   	return FormatInt(the x of pPoint) & "," & FormatInt(the y of pPoint)
   end handler