LiveCode Forums.

Code: Select all

function specialFolderPathTMM pGenericName
   # below line is the version you need if your dev environment *is* linux
   #if the environment is "linux" or the environment is "development" then
   if the environment is "linux" then
      put specialFolderPath(pGenericName) into tPath
      if the result is "folder not found" or tPath is nothing or pGenericName is "desktop" then
         # verify xdg utility exists and is responsive first
         if not (xdgGetPath("") ends with "not found") then 
            put xdgGetPath(pGenericName) into tPath            
         end if
      end if
   else
      put specialFolderPath(pGenericName) into tPath
   end if
   return tPath
end specialFolderPathTMM

function xdgGetPath pCommonFolderName
   # get common user directory paths on Linux.
   # BEHAVIOR UNDEFINED ON NON-LINUX; it could just as easily cook your goldfish
   # with a weasel patty on the side as produce usable output in those other OSes
   # (depends on weasel patty patch status in posix sub-system). 
   # as of 2019 feb 10, common linux user folder names supported by xdg-user-dir are:
   # DESKTOP, DOWNLOAD, DOCUMENTS, VIDEOS, PICTURES, MUSIC,
   # PUBLICSHARE, TEMPLATES
   # xdg-user-dir should be on any linux distro that uses systemd as a system manager,
   # plus possibly others.
   # If xdg-user-dir is not on the system, you'll get an error message in the return,
   # which should end with "not found".
   # If the folder name submitted is not valid or not defined, you just get
   # the user folder by default.
   put shell("xdg-user-dir " & toUpper(pCommonFolderName)) into tShellMessage
   replace return with empty in tShellMessage
   return tShellMessage
end xdgGetPath