LiveCode Forums.

Code: Select all

local sRect, sClickAreasA, sClickedArea
/* clickareas array - clicking a drag handle will assign one of elements 1-8 to sClickedArea:
1: topLeft, 2: topCentre, 3: topRight
4: midLeft, 5: midRight
6: bottomLeft, 7: bottomCentre, 8: bottomRight
if the clickLoc is in none of the above then sClickedArea is 'grab' 
*/

on mouseDown
    if the editControls of this card then
        setClickable true
        put getClickLocation(the clickLoc) into sClickedArea
    end if
    if sClickedArea = "grab" then grab me
end mouseDown

command setClickable pMode // bool
    if pMode = true then
        if the uSelected of me then exit setClickable
        send "unSelectAll" to this card
        setCursor
        select me
        set the uSelected of me to true
    else
        if not the uSelected of me then exit setClickable
        resetCursor
        set the uSelected of me to false
    end if
end setClickable

command clearClickAreas // reset drag handle rect definitions
    put empty into sClickAreasA
end clearClickAreas

command setClickAreas // get a 9 pixel rect around each of the 8 drag handles
    lock screen
    set the rect of the templateGraphic to "0,0,9,9"
    set the style of the templateGraphic to "rectangle"
    set the visible of the templateGraphic to false
    create graphic "temp"
    reset the templateGraphic
    // 1 -  topleft
    set the loc of graphic "temp" to the topleft of me
    put the rect of graphic "temp" into sClickAreasA[1]
    // 2 - topCentre
    set the loc of graphic "temp" to item 1 of the loc of me, the top of me
    put the rect of graphic "temp" into sClickAreasA[2]
    // 3 - topRight
    set the loc of graphic "temp" to the topRight of me
    put the rect of graphic "temp" into sClickAreasA[3]
    // 4 - midLeft
    set the loc of graphic "temp" to the left of me, item 2 of the loc of me
    put the rect of graphic "temp" into sClickAreasA[4]
    // 5 - midRight
    set the loc of graphic "temp" to the right of me, item 2 of the loc of me
    put the rect of graphic "temp" into sClickAreasA[5]
    // 6 - bottomLeft
    set the loc of graphic "temp" to the bottomLeft of me
    put the rect of graphic "temp" into sClickAreasA[6]
    // 7 - bottomCentre
    set the loc of graphic "temp" to item 1 of the loc of me, the bottom of me
    put the rect of graphic "temp" into sClickAreasA[7]
    // 8 - bottomRight
    set the loc of graphic "temp" to the bottomRight of me
    put the rect of graphic "temp" into sClickAreasA[8]
    //
    delete graphic "temp"
end setClickAreas

function getClickLocation pClickLocation // define which drag handle is clicked
    local tLocation
    if pClickLocation is within sClickAreasA[1] then
        return "topLeft"
    else if pClickLocation is within sClickAreasA[2] then 
        return "topCentre"
    else if pClickLocation is within sClickAreasA[3] then
        return "topRight"
    else if pClickLocation is within sClickAreasA[4] then
        return "midLeft"
    else if pClickLocation is within  sClickAreasA[5] then
        return "midRight"
    else if pClickLocation is within sClickAreasA[6] then
        return "bottomLeft"
    else if pClickLocation is within sClickAreasA[7] then
        return "bottomCentre"
    else if pClickLocation is within sClickAreasA[8] then
        return "bottomRight"
    else
        return "grab"
    end if
end getClickLocation

on mouseEnter
    setClickAreas
    setCursor
end mouseEnter

command setCursor
    if not the editControls of this card then 
        resetcursor
        exit setCursor
    end if
    set the lockCursor to true
    set the cursor to hand
    repeat with x = 1 to 8
        if the mouseLoc is within sClickAreasA[x] and the uSelected of me then
            set the cursor to cross
            exit  repeat
        end if
        set the cursor to hand
    end repeat
end setCursor

command resetCursor
    set the lockCursor to false
    set the cursor to arrow
end resetCursor

on mouseMove
    setCursor
    if the mouse is down then
        local tRect
        lock screen
        put the rect of me into tRect
        if sClickedArea = "grab" then pass mouseMove
        switch sClickedArea
            case "topLeft"
                put item 1 of the mouseLoc into item 1 of tRect
                put item 2 of the mouseLoc into item 2 of tRect
                break
            case "topCentre"
                put item 2 of the mouseLoc into item 2 of tRect
                break
            case "topRight"
                put item 1 of the mouseLoc into item 3 of tRect
                put item 2 of the mouseLoc into item 2 of tRect
                break
            case "midleft"
                put item 1 of the mouseLoc into item 1 of tRect
                break
            case "midRight"
                put item 1 of the mouseLoc into item 3 of tRect
                break
            case "bottomLeft"
                put item 1 of the mouseLoc into item 1 of tRect
                put item 2 of the mouseLoc into item 4 of tRect
                break
            case "bottomCentre" 
                put item 2 of the mouseLoc into item 4 of tRect
                break
            case "bottomRight"
                put item 1 of the mouseLoc into item 3 of tRect
                put item 2 of the mouseLoc into item 4 of tRect
                break
        end switch
        set the rect of me to tRect
    end if
end mouseMove

on mouseLeave
   resetCursor
end mouseLeave

Code: Select all

on mouseDown
    unSelectAll
end mouseDown

command unSelectAll
    repeat with x = 1 to the number of controls of this card
        if the isEditable of control x of this card then
            dispatch "setClickable" to control x of this card with false
        end if
    end repeat
    select empty
end unSelectAll

command prepFields
    repeat with x = 1 to the number of fields
        if the isEditable of field x then
            set the traversalOn of field x to not the editControls of me
            set the lockText of field x to the editControls of me
        end if
    end repeat
end prepFields

Code: Select all

on hiliteChanged
    set the editControls of this card to the hilite of me
    unselectAll
    prepFields
end hiliteChanged